Image backup & restore mit Drivesnapshot.
Windows im Netzwerk sichern & wiederherstellen.
2020-09-11 © ctaas.de, Arno Schröder § Impressum

#cs --- -- -- -- -- -- -- -- -- -- -- -- -- --
AutoIt Version: 3.x    | getestet mit: Drivesnapshot Version 1.48
Autor: © A. Schröder   | Version: 2020-09-04

SKRIPT-FUNKTIONEN:
- Alle lokalen Laufwerke (C: bis Z:) sowie ggf. zum booten notwendigen System-Partitionen (wie z. B. 'System-reserviert') werden in einer lokalen Netzwerkfreigabe gesichert.
- Es werden alle vorhandenen SSDs, Festplatten-Laufwerke u. ä. gesichert, andere Laufwerke wie z. B. CD-ROM/DVD/Blu-ray Laufwerke werden automatisch übersprungen.
- Für jede Sicherung wird ein ausführliches Protokoll angelegt.
- Zur besseren Übersicht wird für jede Sicherung ein extra Verzeichnis angelegt, so dass man bei Bedarf auch auf ältere Sicherungen zurückgreifen kann.
- Das Script wurde getestet mit:
      - Windows 10, 8.1, 8, 7, Vista, XP, 2000;
      - Windows Server 2008, 2008 R2; 2012, 2012 R2, 2016, 2019 (auch Datacenter)
- Bei einem Exchange Server 2010 werden die Transaktionsprotokolle/Transaktionslogs nach einer erfolgreichen Sicherung gelöscht.
- Beachtet: Will man das Script für Windows 2000 kompilieren, dann benötigt man die ältere Version 3.3.8.1 von AutoIt (Direktlink).
#ce --- -- -- -- -- -- -- -- -- -- -- -- -- --

; Dieses Script benötigt Admin-Rechte. This script requires full administrative rights.
#RequireAdmin

; Wird benötigt für Datumsfunktionen und zum bestimmen des Hash-Datei Pfades. Required for date and hash functions.
#include <Date.au3>
#include <File.au3>
#include <Array.au3>

; -- -- -- -- -- -- -- -- -- -- -- -- -- -- --
; VARIABLEN DEFINIEREN:
Local $i_Startzeit=_NowCalc() ; Startzeit speichern, um die Dauer der Sicherung zu ermitteln. Save start time and date.
Local $s_Computername=EnvGet("COMPUTERNAME") ; Computername auslesen. Save hostname.

; Hinweis zum Start der Datensicherung. A Note to the users, that a backup starts. Hinweis: Der Unterstrich '_' am Zeilenende kennzeichnet einen Zeilenumbruch des Befehls.
SplashTextOn("BCK-UP © ctaas.de - automatische Datensicherung:", "Im Hintergrund läuft eine Datensicherung. Du kannst während der Sicherung weiter arbeiten, es kann es " _
& "jedoch zu leichten Verzögerungen kommen. Dieser Hinweis beendet sich selbstständig, wenn die Datensicherung abgeschlossen wurde.", 450, 100, -1, -1, 22, "Tahoma", 10)

; -- -- -- -- -- -- -- -- -- -- -- -- -- -- --
; NETZWERK VERBINDEN:
DriveMapDel("y:") ; Ggf. Netzlaufwerk abmelden, falls irgendein anderes Laufwerk bereits gemappt ist. Unmount a possible mounted network share.

; Netzlaufwerk für die Backup-Images mappen. Hier die eigenen Zugangsdaten für die Netzwerkfreigabe eingeben. Map network share for the backups (this data must be modified). <####!
DriveMapAdd("y:", "\\192.168.0.9\share", 0, "domain_oder_hostname\username", "password")
; Wichtig: Den domain (Domänennamen) bzw. Hostnamen (Computernamen) sollte man immer mit angeben.
; Insbesondere bei Freigaben unter Windows 10 ab der Version 20.04 und vergleichbare Serverversionen (erhöhte Sicherheitsanforderungen) kann dies zwingend notwendig sein.

; OPTIONAL/RDX/WECHSELDATENTRÄGER: EXTRA FREIGABE FÜR DIE snapshot.exe/snapshot64.exe:
; Wenn man öfters verschiedene Systeme sichert und zur Sicherung ein Wechseldatenträger-Laufwerk (wie z. B. ein RDX Laufwerk) verwendet,
; dann sollte man den voreingestellten festen Pfad zum Sicherungsprogramm 'y:\snapshot\snapshot.exe' so verändern,
; dass dieser auf eine separate/statische Freigabe verweist. Also z. B. so: '\\Hostname\Freigabe\snapshot\snapshot.exe'.
; So ist dann auch eine einfache und schnelle zentrale Aktualisierung der snapshot.exe/snapshot64.exe möglich.
; Um den Zugriff auf diese UNC-Freigabe zu gewährleisten muss man hier noch die entsprechenden Zugangsdaten eingeben.
; Optional aktivieren: Hier also bei Bedarf die doppelten Semikolon [;;] am Zeilenanfang entfernen und die entsprechenden Logindaten eingeben: <####!

;; #include <WinNet.au3>
;; _WinNet_AddConnection2("", "\\hostname\share", "domain_oder_hostname\username", "password")
; Wichtig! Bitte dabei beachten: Die ggf. zweite Freigabe für die snapshot.exe darf nicht nur Leserechte besitzen.
; Diese Freigabe muss beschreibbar sein, auch wenn man die Images in einer anderen Freigabe abgelegt.

; -- -- -- -- -- -- -- -- -- -- -- -- -- -- --
; OPTIONAL/RDX/WECHSELDATENTRÄGER: ALTE SICHERUNG IMMER LÖSCHEN:
; Verwendet man zum Sichern ein Wechseldatenträger-Laufwerk (wie z. B. ein Tandberg RDX QuickStore), dann sollte man immer vor einer neuen Sicherung, die alte Sicherung von dem Backup-Medium löschen.
; Dies ist unter anderem notwendig um sicherzustellen, dass immer genügend freier Speicherplatz auf dem Wechsel-Speichermedium vorhanden ist.
; Auf dem Backup-Medium (der Cartridge/der Wechselfestplatte) wird dann gem. dem Großvater-Vater-Sohn Generationenprinzip nur eine Sicherung pro Tag gespeichert.
; Man hat also die Wahl zwischen:
; a) Möchte man alte Sicherungen nicht aufheben, dann muss man bei den folgenden Zeilen die doppelten Semikolon [;;] am Zeilenanfang entfernen. Oder...
; b) Möchte man mehrere alte Sicherungen aufheben (z. B. bei Sicherungen auf einem NAS), dann darf man die doppelten Semikolon hier nicht entfernen.

; Optional aktivieren: Prüfen ob eine alte Sicherung existiert. As an option: Check if exists an old backup. Remove the two ;; if u use removable disks (RDX) for backup. <####!
;; If FileExists("y:\Images\" &$s_Computername) Then
     ; Falls ja (falls eine alte Sicherung existiert), dann altes Verzeichnis löschen. If yes, then delete old backup.
;;   DirRemove("y:\Images\" &$s_Computername,1)
;; EndIf

; -- -- -- -- -- -- -- -- -- -- -- -- -- -- --
; VERZEICHNISSE UND LOGFILE FÜR DIE SICHERUNGEN ANLEGEN:
; Prüfen ob ein Verzeichnis mit dem Computername für die Images vorhanden ist. Check if hostname directory exists.
If Not FileExists("y:\Images\" &$s_Computername) Then
  ; Wenn noch kein Verzeichnis vorhanden ist, dann ein neues anlegen. Create new directory.
  DirCreate("y:\Images\" &$s_Computername)
EndIf

; Logfile öffnen, falls noch kein Logfile vorhanden ist wird ein neues angelegt. Open Logfile if exist, or create new one.
$h_file=FileOpen("y:\Images\" &$s_Computername&"\_Logfile_" &$s_Computername&".txt", 1)

; Schreibzugriff prüfen. Check if file opened for writing OK.
If $h_file=-1 Then ; Falls der Schreibzugriff nicht möglich ist...
  DriveMapDel("y:") ; ... das Netzlaufwerk abmelden. Der Fehler tritt z. B. auf wenn kein RDX-Medium eingelegt wurde (neues Medium vergessen) oder wenn das RDX-Medium defekt ist. 
  ; Unmount network share, if no backup RDX media is inserted or if the backup RDX media is defective.
  ;; _WinNet_CancelConnection2("\\hostname\share") ; Die optionale zweite Freigabe für die snapshot.exe beenden ebenso beenden. <####!
  ; Falls der Schreibzugriff nicht möglich ist, eine Fehlermeldung ausgeben. Throw a error message, if write is impossible.
  MsgBox(0, "Fehler:", "NAS/RDX nicht erreichbar."&@crlf&"Automatische Datensicherung fehlgeschlagen."&@crlf&"Bitte verständigen sie ihren Administrator."&@crlf&@crlf&"Dieser Hinweis beendet sich selbstständig in 5 Minuten.", 300)
  ; Diese MessageBox beendet sich nach 5 Minuten (300 Sekunden) selbstständig. Setzt man den Wert auf 0 oder lässt die Zeitangabe komplett weg, dann bleibt die Meldung ohne Timeout dauerhaft stehen (bis man die Meldung mit [OK] schließt).
  Exit 1
EndIf

; Startzeit Protokollieren. Save start time in Logfile.
FileWriteLine($h_file, "---[ " &$s_Computername &": Letzte Ausführung siehe Ende Protokoll ]---" &@CRLF &"Sicherungsstart: " &_Now())

; Neues Verzeichnis zur Sicherung anlegen (@YEAR&@MON&@MDAY = das aktuelle Datum). Create new data backup directory.
DirCreate("y:\Images\" &$s_Computername &"\" &@YEAR&@MON&@MDAY)

; -- -- -- -- -- -- -- -- -- -- -- -- -- -- --
; SCHLEIFE ÜBER ALLE ZU SICHERNDE LAUFWERKE & LAUFWERKSTYP BESTIMMEN:
Local $bck_up_drives="" ; Variable für die zu sichernden Laufwerke. Enthält später Beispielsweise C:+, C:+D: 
Local $i_disk
For $i_disk = Asc("C") To Asc("Z") Step 1 ; For (loop) Schleife über die Laufwerksbuchstaben von c: bis z: (anpassbar).
  Local $s_disk = Chr ($i_disk) ; und aktuellen Laufwerksbuchstaben in der Variable $s_disk speichern. $s_disk enthält dann z. B.: C, D, E ... X, Y, Z.
  ; ergänzende Information: Der ASCII/Windows-1252-Zeichencode vom Zeichen C Entspricht der Zahl 67.
 
  ; Laufwerkstyp abfragen (z. B. 'C:\'). Ist das Laufwerk eine Festplatte? Wenn ja (Fixed) dann sichern, falls nein (weil z. B. DVD-ROM oder Netzlaufwerk) dann überspringen.
  If DriveGetType($s_disk &":\")="Fixed" Then
        $bck_up_drives &= $s_disk & ":+" ; entspricht: $bck_up_drives = $bck_up_drives + $s_disk + ":+". Das gefundene Laufwerk der Variable der zu sichernden Laufwerke hinzufügen.
  EndIf; $bck_up_drives enthält hier Beispielsweise C:+, C:+D:+, C:+D:+E:+, ...
Next

; Das letzte '+' Zeichen muss noch entfernt werden. 'C:+D:+E:+' muss Beispielsweise so gekürzt werden 'C:+D:+E:'.
$bck_up_drives=StringTrimRight ( $bck_up_drives, 1 ) ;  1 Zeichen rechts (right) vom String der Variable entfernen (trim).

Local $s_dif_backup="" ; Variable initialisieren (für das differentielle Backup). Leer ("") bedeutet erst einmal kein differentielles Backup. Hinweis: Diese Definition nicht löschen.

  ; -- -- -- -- -- -- -- -- -- -- -- -- -- --
  ; OPTIONAL: DIFFERENTIELLES BACKUP:
  ; Zum Aktivieren der differentiellen Funktion die Kommentarzeilen [#cs] und [#ce] löschen.
  ; ergänzender Hinweis: Die ggf. weiteren System-Partitionen (wie Beispielsweise HD1-1.sna)  werden nur bei einem Voll-Backup gesichert.
  ; Daher sollte man in regelmäßigen Abständen auch ein Voll-Backup durchführen (z. B. einmal Wöchentlich).
#cs (Kommentar Start) <####!
  ; Prüfen ob eine Hash-Datei vom ersten Laufwerk ('C') vorhanden ist.
   $a_hsh_pfad=_FileListToArrayRec('y:\Images\' &$s_Computername, "*_snapshot_ful_C.hsh",1 , 1 )
    
  ; Ggf. gefundenen Hashdateien sortieren:
  ; Da die Namen das Datum enthalten wird hier auf Grund der absteigenden Sortierung immer das aktuellste Datum als erster Array-Eintrag bereitgestellt.
  _ArraySort($a_hsh_pfad,1)
  ; $a_hsh_pfad[0] enthält dann immer den anteiligen Pfad zu der zuletzt verwendeten voll-Backup .hsh-Datei also z. B. '20191120\PCNAME-191120-drivesnapshot-ful-C.hsh'

  If $a_hsh_pfad="" Then
    ; Wenn keine Hash-Datei (*.hsh) gefunden wurde, den Übergabewert zur differentiellen Sicherung auf leer setzen. Ein neues voll-Backup (ful) wird angelegt.
    FileWriteLine($h_file, "Voll-Backup (ful).") 
    $s_dif_backup="" ; Ist hier eigentlich unnötig, da der Wert oben schon leer definiert wurde. Es wurde zum besseren Verständnis trotzdem nochmal hier eingefügt.
  Else
    ; Und wenn eine Hash-Datei (*.hsh) gefunden wurde, dann den Pfad darauf setzen. Ein neues differentielles Backup (dif) wird angelegt.
    ; $a_hsh_pfad[0] enthält z. B.: '20191120\PCNAME-191120-drivesnapshot-ful-C.hsh'.
    ; Durch den austausch der festen Laufwerksangabe '_C.hsh' durch die Snapshot-Variable '_$disk.hsh', kann snapshot auch alle weiteren Laufwerke D: bis Z: differential mit sichern.
    $a_hsh_pfad[0]=StringReplace ($a_hsh_pfad[0], "_C.hsh", "_$disk.hsh",0,0) ; Laufwerk 'C' (nicht case sensitive) wird durch '$disk' ersetzt.
    ; $a_hsh_pfad[0] enthält nun z. B.: '20191120\PCNAME-191120-drivesnapshot-ful-$disk.hsh'.

    ; Den Pfad zum Hash-File um den Drivesnapshot-Parameter, den Laufwerksbuchstaben, den Sicherungsordner und Computername ergänzen.
    $s_dif_backup="-hy:\Images\" &$s_Computername &"\" &$a_hsh_pfad[0]
     
    ; Im Logfile speichern, auf welches Voll-Backup sich das Dif-Backup bezieht. StringMid ermittelt die ersten 8 Zeichen des Strings, diese enthalten das Datum vom Voll-Backup.
    FileWriteLine($h_file, "Differentielles Backup (dif) zur Sicherung: " &  StringMid($a_hsh_pfad[0],1,8) )
  EndIf
#ce (Kommentar Ende) <####!

; -- -- -- -- -- -- -- -- -- -- -- -- -- --
; LAUFWERK SICHERN:
; Meldung im Tray anzeigen:
TrayTip("BCK-UP © ctaas.de:", "sichere Laufwerk(e) " & $bck_up_drives, 30, 1)

; Start der Sicherung:                        $bck_up_drives = C:+D+E+
$i_error=RunWait("y:\snapshot\snapshot.exe " &$bck_up_drives &" y:\Images\$computername\20$date\$computername_$date_snapshot_$type_$disk.sna --AutoBackupSize:8192 --ALLWriters -Gx -R --LogFile:y:\Images\$computername\20$date\_logfile.txt " &$s_dif_backup)
;            ... "\\hostname\share\snapshot.exe ...   ; Alternative 1: Die snapshot.exe in der zweiten Freigabe ablegen. Der Zugriff auf die snapshot.exe erfolgt hier über UNC-Pfade.
;            ... "c:\Sicherung\snapshot64.exe ...     ; Alternative 2: Die snapshot.exe/snapshot64.exe lokal auf dem zu sichernden System ablegen. Die snapshot64.exe ist nur bei 64-Bit Systemen möglich.

; Errorlevel im Logfile speichern.
FileWriteLine($h_file, "Sicherungsergebnis für das Laufwerk " &$bck_up_drives &" (0=ok alles andere Fehler): " &$i_error )

; -- -- -- -- -- -- -- -- -- -- -- -- -- -- --
; SICHERUNGS ENDE:
; Sicherungsende (Datum & Zeit) speichern und Sicherungsdauer berechnen und speichern. Save end date & time and calculate the duration of the backup.
FileWriteLine($h_file, "Sicherungsende: " &_Now() &@CRLF &"Sicherungsdauer in Minuten: " &_DateDiff('n',$i_Startzeit,_NowCalc() ) &@CRLF)
FileClose($h_file)

DriveMapDel("y:") ; Netzlaufwerk abmelden. Unmount network share.
;; _WinNet_CancelConnection2("\\hostname\share") ; Die optionale zweite Freigabe für die snapshot.exe beenden.

SplashOff() ; Meldungstext ausblenden und beenden. Dissable note for the users and exit.
Exit 0 ; Skript-Ende.